进口咖啡清关流程:用asp怎么编写验证码?

使用ASP生成图片彩色校验码

49行代码,三个文件
Asp文件：Code.Asp
数据文件：body.Fix , Head.Fix

用法：<img src="code.asp">

<%
Option Explicit
Response.buffer=true
NumCode
Function NumCode()
Response.Expires = -1
Response.AddHeader "Pragma","no-cache"
Response.AddHeader "cache-ctrol","no-cache"
dim zNum,i,j
dim Ados,Ados1
Randomize timer
zNum = cint(8999*Rnd+1000)
Session("GetCode") = zNum
dim zimg(4),NStr
NStr=cstr(zNum)
For i=0 to 3
zimg(i)=cint(mid(NStr,i+1,1))
Next
dim Pos
set Ados=Server.CreateObject("Adodb.Stream")
Ados.Mode=3
Ados.Type=1
Ados.Open
set Ados1=Server.CreateObject("Adodb.Stream")
Ados1.Mode=3
Ados1.Type=1
Ados1.Open
Ados.LoadFromFile(Server.mappath("body.Fix"))
Ados1.write Ados.read(1280)
for i=0 to 3
Ados.Position=(9-zimg(i))*320
Ados1.Position=i*320
Ados1.write ados.read(320)
next
Ados.LoadFromFile(Server.mappath("head.fix"))
Pos=lenb(Ados.read())
Ados.Position=Pos
for i=0 to 9 step 1
for j=0 to 3
Ados1.Position=i*32+j*320
Ados.Position=Pos+30*j+i*120
Ados.write ados1.read(30)
next
next
Response.ContentType = "image/BMP"
Ados.Position=0
Response.BinaryWrite Ados.read()
Ados.Close:set Ados=nothing
Ados1.Close:set Ados1=nothing
End Function
' Asp code Created by BlueIdea.COM Web Team V37 2003-7-25
%>

代码解释:

Response.buffer=true
NumCode
Function NumCode()
Response.Expires = -1
Response.AddHeader "Pragma","no-cache"
Response.AddHeader "cache-ctrol","no-cache"
dim zNum,i,j
dim Ados,Ados1
Randomize timer
生成随机四位数字：
zNum = cint(8999*Rnd+1000)
传递给session
Session("GetCode") = zNum
该for循环是将随机数字放入一个下标3的数组，便于提供给后面的阵列变换
dim zimg(3),NStr
NStr=cstr(zNum)
For i=0 to 3
zimg(i)=cint(mid(NStr,i+1,1))
Next
dim Pos

'定义二个 ADODB.Stream binary对象,作图像数据操作之用:

set Ados=Server.CreateObject("Adodb.Stream")
Ados.Mode=3
Ados.Type=1
Ados.Open
set Ados1=Server.CreateObject("Adodb.Stream")
Ados1.Mode=3
Ados1.Type=1
Ados1.Open
'载入0~9的数字数据10x100的，Gbr的阵列数据,每个320字节,10个数字3200byte
'BGR一个点,10x10个点一个数字，一个点三个字节(二进制8位，16进制 00~FF)
'一行10个点 30字节 + 行结束标记 00 00 二字节 32字节，所以一个10x100宽小于长的图像每个数字10x10是320字节
'长大于宽的则无行结束标记 0000,直接是300字节
这些就是BMP 24bit的数据详细信息了
‘至于头部，也很简单，包含长宽，图像开始标记等等~~才54字节，远没jpg什么的复杂

Ados.LoadFromFile(Server.mappath("body.Fix"))
Ados1.write Ados.read(1280)
'第一个for循环,按生成的随机数字顺序从 10X100的数字阵列中提取出相应的四个数字
但是竖排的数字阵列
for i=0 to 3
Ados.Position=(9-zimg(i))*320
Ados1.Position=i*320
Ados1.write ados.read(320)
next
'清空已经用完的ADOS的数据，调入替换新的图像头54字节的头文件
Ados.LoadFromFile(Server.mappath("head.fix"))
Pos=lenb(Ados.read())
Ados.Position=Pos '指定Pos位置,即可再偏移54字节的位置添加图形数据
第二个for循环，进行数字的阵列变换，由竖排的块转换为横排的数字块
方法是隔320字节抽取4次30字节写入ados对象，再抽取偏移第二行的图像数据
30字节是因为bmp 宽大于长时无00 00的行结束标记
for i=0 to 9 step 1
for j=0 to 3
Ados1.Position=i*32+j*320
Ados.Position=Pos+30*j+i*120
Ados.write ados1.read(30)
next
next
Ados.Position=0
response.BinaryWrite直接向客户端发送图像数据
Response.ContentType = "image/BMP"
Response.BinaryWrite Ados.read()
Ados.Close:set Ados=nothing
Ados1.Close:set Ados1=nothing
End Function

数字和字母组合并生成图片的验证码祥解
大家经常在网上登陆的时候经常会看到让你输入验证码，有的是文字的，有的呢是图片，比如chinaren.com校友录中留言的时候，我们就会看到数字图片验证码；网上关于数字文字验证码实现方法的相关资料很多，而我们这里介绍的是数字和字母随机组成的并且生成图片的验证码的实现方法。看起来很复杂、其实很简单的，大家跟着我往下看：

首先，我们先介绍一下设计思路，数字和字母的随机组合生成验证码，然后将验证码生成图片，这里“数字和字母的组合”应该是随机取出来的；如果是专门的数字验证码，我们可以这样实现：

ycodenum=4 '验证码的位数，或者说成个数
for i=1 to ycodenum
Randomize '初始化随机数发生器
ycode=ycode&Int((9*Rnd)) 'rnd是随机数，从0到1之间的任意实数，这里获得0到9之间的整数
next

response.write ycode '就可以输出数字验证码（4位）

然而，我们要让数字和字母同样随机生成，这里我们可以用到数组来实现这种效果，如下：

ychar="0,1,2,3,4,5,6,7,8,9,A,B,C,D,E,F,G,H,I,J,K,L,M,N,O,P,Q,R,S,T,U,V,W,X,Y,Z" '将数字和大写字母组成一个字符串
yc=split(char,",") '将字符串生成数组
ycodenum=4
for i=1 to ycodenum
Randomize
ycode=ycode&yc(Int((35*Rnd))) '数组一般从0开始读取，所以这里为35*Rnd
next

response.write ycode

现在看看输出结果是不是数字和字母随机组合的呢？

下面看看怎样生成图片，这个也许有些朋友知道：asp不能生成图片，必须使用asp组件。不错，我们这里使用的是ASP图象组件shotgraph。有一点大家注意，服务器不是自己的不能用哦，因为你装不了这组件。

组件的下载地址：http://www.csdn.com.cn/download/ShotGraph.rar，至于怎么注册，这里就不多说了，网上有很多资料

我们看看生成图片的代码：

ychar="0,1,2,3,4,5,6,7,8,9,A,B,C,D,E,F,G,H,I,J,K,L,M,N,O,P,Q,R,S,T,U,V,W,X,Y,Z" '将数字和大写字母组成一个字符串
yc=split(char,",") '将字符串生成数组
ycodenum=4
for i=1 to ycodenum
Randomize
ycode=ycode&yc(Int((35*Rnd))) '数组一般从0开始读取，所以这里为35*Rnd
next

Response.Clear
Response.ContentType="image/gif"
set obj=Server.CreateObject("shotgraph.image")
x=55 '图片的宽
y=26 '图片的高
obj.CreateImage x,y,8 '8是图片的颜色8位
obj.SetColor 0,55,126,222
obj.SetColor 1,255,255,255

obj.CreatePen "PS_SOLID",1,0
obj.SetBgColor 0
obj.Rectangle 0,0,x-1,y-1
obj.SetBkMode "TRANSPARENT"
obj.CreateFont "Arial",136,18,1,False,False,False,False
obj.SetTextColor 1
obj.TextOut 5,4,ycode&" "

img=obj.GifImage(-1,1,"")
Response.BinaryWrite (img)

针对以上代码也就是说shotgraph普通的画图的原理请参考：http://www.pconline.com.cn/pcedu/empolder/wz/asp/10204/45207.html

asp中使用图片验证码的方法
作者：Loster(OICQ:181306) 如果转载，请勿去掉此行，谢谢。

现在许多网站的登陆都需要输入验证码，验证码一般都是以图片的形式显示的。这样一来，能提高登陆的安全性，防止暴力猜解密码。为何要用图片显示验证码？试想，如果只是生成文本的验证码，破解人可以利用类似于小偷的技术，先把你这个页面读取，然后分析出验证码，最后进行暴力猜解。这样的话，验证码就没有任何实际意义了。废话少说，下面我就开始说一说怎样实现asp中显示图片验证码。

要实现asp中显示图片验证码，首先需要以下三个文件：

GetCode.asp (用于生成图片验证码)

head.fix (图片头)

body.fix (图片主体)

你也许会问，这些文件我从哪里可以得到呢？不用着急，这些文件在dvbbs7.0里面有。我也是在研究了dvbbs7.0里面的验证码之后才学会如何使用图片验证码的。

首先看getcode.asp文件，里面有几行是这样的：

Ados.LoadFromFile(Server.mappath("body.Fix"))
Ados1.write Ados.read(1280)
For i=0 To 3
Ados.Position=(9-zimg(i))*320
Ados1.Position=i*320
Ados1.write ados.read(320)
Next
Ados.LoadFromFile(Server.mappath("head.fix"))

看到body.fix和head.fix了吗？这里指的是他们与getcode.asp的相对位置。如果他们三个文件在一个目录里面，就按照以上的写法就可以了。如果不是，就需要写出他俩与getcode.asp的相对位置。比如：如果getcode.asp在根目录下，body.fix&head.fix在根目录下的test文件夹下，那么，上面的代码就需改为：

Ados.LoadFromFile(Server.mappath("test/body.Fix"))
Ados1.write Ados.read(1280)
For i=0 To 3
Ados.Position=(9-zimg(i))*320
Ados1.Position=i*320
Ados1.write ados.read(320)
Next
Ados.LoadFromFile(Server.mappath("test/head.fix"))

这样，才能保证图片显示的正常。

如何调用？

很简单，只需要这样：

<img src=getcode.asp border=0>

即可。

每当在调用getcode.asp之后，会自动生成一个session,这个session存储着和验证图片上显示的一样的四位数字。你只需把接收到的验证码和这个session比较，然后判断验证码是否输入正确。当然，最好像这样：

If Cstr(Trim(接收的变量名))=Cstr(Session("GetCode")) Then

Response.Write ("OK!")

Else

Response.Write ("No!")

End If

呵呵，至此，啰嗦完毕。希望你在看完本文后有所启发。当然，本人水平有限，文中难免出现错误，欢迎大家指正。

有人可能要问，图片能不能修改啊，答案是肯定的，网上有相关文章，你可以去查查。

附：http://www.loster.net/aspfile/getcode.rar getcode.asp,head.fix,body.fix文件压缩包

有随即数函数．

w