为什么学金融 文书:ASP的一个FUNCTION 每句是什么意思???

'本函数的功能在SQL语句中，看懂了SQL语句也就了解函数功能
Function GetConnectNewsList(kWord,NewsId)
Dim Result '定义一个叫‘结果’的变量
Result="" '给变量赋空值
If kWord="" Or IsNULL(kWord) Then '如果参数kWord为空或者为NULL值
GetConnectNewsList=Result '返回函数值=Result
Exit Function '并退出函数
End If
Dim arr,I
arr=Split(kWord,",",NewsKeyWordListNum,1)'把参数kWord每个字母用逗号隔开，赋给数组arr
Dim tSql
tSql="" '定义并赋变量tSql为空

For I=0 To UBound(arr) '循环开始：从数组arr第一个到最后一个
'下面两句是SQL语句，意思是查询标题中包含arr数组的值
If tSql<>"" THen
tSql=tSql & " OR Title Like '%"&arr(I)&"%' OR KeyWord Like '%"&arr(I)&"%'"
Else
tSql=tSql & " Title Like '%"&arr(I)&"%' OR KeyWord Like '%"&arr(I)&"%'"
End If
Next

If tSql<>"" Then
'SQL语句，查询满足上面条件而且Id号不=参数NewsId，以Id按降序排列
tSql=" Where (" & tSql &") And Id<>"&NewsId &_
" Order By Id DESC"
End If

Dim Sql
'SQL语句，从表view_NewsInfo中查询满足上面条件前10行列出列名为Id,Title,Class,FilePath,AddTime的值
Sql="Select Top 10 Id,Title,Class,FilePath,AddTime From view_NewsInfo" & tSql
Dim Rs
'执行sql语句，结果赋给Rs
Set Rs=Conn.ExeCute(Sql)
'循环输出满足sql语句的行，Rs("")里的数是从数据库读出
While Not Rs.Eof
'行号，超链接标记 超链接地址 超链接内容
Result=Result & "<li><a href=""../../" &Rs("FilePath")&""">"&Rs("Title")&"</a>"
'此函数返回时间，2是参数，决定时间格式
Result=Result & " ["&FormatDateTime(Rs("AddTime"),2)&"]" & "</li>"
Rs.MoveNext '记录下移
Wend
'以下2句是关闭创建的对象
Rs.Close
Set Rs=Nothing
'返回函数值
GetConnectNewsList=Result
End Function
'要学习ASP就下载些资料看吧：www.ibook8.com。别忘了下载阅读器

function表示函数的定义．

VBScript语句的函数

^_^我只能告诉你这个东东是用来做一个新闻标题检索的，并且可以用“,”号分开关键词，进行模糊查找,返回前十条数据～～要一句一句翻译给你～～除非你真的请我出来喝茶啦！！呵呵

分子太低了,打字太累了
改了分我再来 ^_^